Forth 2012: ?DO

Interpretation:

Interpretation semantics for this word are undefined.

Compilation:

( C: -- do-sys )

Put do-sys onto the control-flow stack. Append the run-time semantics given below to the current definition. The semantics are incomplete until resolved by a consumer of do-sys such as LOOP.

Run-time:

( n₁ | u₁ n₂ | u₂ -- ) ( R: -- loop-sys )

If n₁ | u₁ is equal to n₂ | u₂, continue execution at the location given by the consumer of do-sys. Otherwise set up loop control parameters with index n₂ | u₂ and limit n₁ | u₁ and continue executing immediately following ?DO. Anything already on the return stack becomes unavailable until the loop control parameters are discarded. An ambiguous condition exists if n₁ | u₁ and n₂ | u₂ are not both of the same type.

See:

3.2.3.2 Control-flow stack, 6.1.0140 +LOOP, 6.1.1240 DO, 6.1.1680 I,
6.1.1760 LEAVE, 6.1.1800 LOOP, 6.1.2380 UNLOOP, A.6.2.0620 ?DO.

Rationale:

Typical use:

: X ... ?DO ... LOOP ... ;

Testing:

DECIMAL

: qd ?DO I LOOP ;
T{ 789 789 qd -> }T
T{ -9876 -9876 qd -> }T
T{ 5 0 qd -> 0 1 2 3 4 }T

: qd1 ?DO I 10 +LOOP ;
T{ 50 1 qd1 -> 1 11 21 31 41 }T
T{ 50 0 qd1 -> 0 10 20 30 40 }T

: qd2 ?DO I 3 > IF LEAVE ELSE I THEN LOOP ;
T{ 5 -1 qd2 -> -1 0 1 2 3 }T

: qd3 ?DO I 1 +LOOP ;
T{ 4 4 qd3 -> }T
T{ 4 1 qd3 -> 1 2 3 }T
T{ 2 -1 qd3 -> -1 0 1 }T

: qd4 ?DO I -1 +LOOP ;
T{ 4 4 qd4 -> }T
T{ 1 4 qd4 -> 4 3 2 1 }T
T{ -1 2 qd4 -> 2 1 0 -1 }T

: qd5 ?DO I -10 +LOOP ;
T{   1 50 qd5 -> 50 40 30 20 10   }T
T{   0 50 qd5 -> 50 40 30 20 10 0 }T
T{ -25 10 qd5 -> 10 0 -10 -20     }T

VARIABLE qditerations
VARIABLE qdincrement

: qd6 ( limit start increment -- )    qdincrement !
   0 qditerations !
   ?DO
     1 qditerations +!
     I
     qditerations @ 6 = IF LEAVE THEN
     qdincrement @
   +LOOP qditerations @
;

T{ 4  4 -1 qd6 ->                   0 }T
T{ 1  4 -1 qd6 -> 4  3  2  1       4 }T
T{ 4  1 -1 qd6 -> 1  0 -1 -2 -3 -4 6 }T
T{ 4  1  0 qd6 -> 1  1  1  1  1  1 6 }T
T{ 0  0  0 qd6 ->                   0 }T
T{ 1  4  0 qd6 -> 4  4  4  4  4  4 6 }T
T{ 1  4  1 qd6 -> 4  5  6  7  8  9 6 }T
T{ 4  1  1 qd6 -> 1  2  3          3 }T
T{ 4  4  1 qd6 ->                   0 }T
T{ 2 -1 -1 qd6 -> -1 -2 -3 -4 -5 -6 6 }T
T{ -1  2 -1 qd6 -> 2  1  0 -1       4 }T
T{ 2 -1  0 qd6 -> -1 -1 -1 -1 -1 -1 6 }T
T{ -1  2  0 qd6 -> 2  2  2  2  2  2 6 }T
T{ -1  2  1 qd6 -> 2  3  4  5  6  7 6 }T
T{ 2 -1  1 qd6 -> -1  0  1          3 }T